;;;Begin
  LDX #0           ; clear X reg for indexing

@equipslots
  LDA $6118, X     ; party leader's equip slots
  CMP #0           ; check for no item in slot
  BEQ @nextslot    ; if true, check next equip slot

    CMP #$80         ; otherwise, check for equipped item (#$80 or greater)
    BCS @message3    ; if something equipped here, show message 3 and end

  @nextslot
    INX              ; otherwise, load next equip slot
    CPX #$08         ; see if we've passed the last slot
    BNE @equipslots  ; if not, restart checking procedure (+X)

      JMP @checktail   ; if equip checks clear, go check for tail. Otherwise...

  @message3
    LDA $13          ; show message 3 ("Must remove equipment")
    RTS              ; and end

@checktail
  LDA $602D        ; check Rat's Tail item flag
  BNE @dochange    ; if you don't have it...

    LDA $11          ; ...show message 1 ("Need Tail")
    RTS              ; and end

  @dochange
    JSR @classbump   ; otherwise, go perform class change and return here
    LDA $12          ; show message 2 ("Class change successful")
    RTS              ; and end

@classbump
  LDX $6100        ; party leader's class
  INX              ; bump it to the next class
  CPX #$0C         ; see if we've passed the last class
  BNE @storeclass  ; if not, proceed to store it

    LDX #0           ; otherwise, load first class

  @storeclass
    STX $6100        ; store new class
    INC $56          ; set flag to reenter map (to draw new class gfx)
    RTS              ; and return